Advanced Skybox Shader For Unity

Advanced Skybox Shader

I'm going show you how to make a skybox shader in unity which gives you a large amount of control on how the skybox is going to look like including the colours shown above and below the horizon.

The default skybox that unity provides is decent when dealing with realistic game worlds, but for a stylized world, custom shaders have to be made.
This shader also has a sun just like with the default unity skybox and works with the directional light in the same exact way also a slider which goes from one set of skybox colour values to another is also included so stuff like day/night cycles can be made with ease.
The provided shader gives full control on how the skybox is going to look and is very much optimized.

This is the shader we will be making.

---

Ramen Run (Game In Development)

The Properties Of The Shader

---

We can see a lot of properties being used. The names make it pretty obvious what it's doing.
In this tutorial I am assuming that you have made a couple of shaders before in unity. If not, I urge you to watch a couple of tutorials on basic shaders and then come back. The entire section of code to do this is in the fragment shader and couple of shader flags and tags.
First we'll start off with defining those properties.

1:  Properties  
2:       {  
3:            _SkyColor1("Top Color Day", Color) = (0.37, 0.52, 0.73, 0)  
4:            _SkyColor2("Horizon Color Day", Color) = (0.89, 0.96, 1, 0)  
5:            _SkyColor3("Top Color Night", Color) = (0.2 ,0.4 ,0.6 , 0)  
6:            _SkyColor4("Horizon Color Night",Color) = (0.4, 0.2, 0.1, 0)  
7:            _Transition("Transition Value",Range(0.0 , 1.0)) = 0.5  
8:            _BaseLevel("Base Start Level",Range(-2.0 , 0.0)) = 0.0  
9:            _GradientExponent("Gradient Exponent",Range(1,100)) = 1  
10:           _SunColor("Sun Colour",Color) = (0.8,0.4,0.0)  
11:           _Scaling("Sun Scaling Factor",Range(1,350)) = 10  
12:           _SunRim("Sun Rim",Range(0.5,1.0)) = 0.8  
13:       }  

Then in the sub shader on top we specify these tags:

 Tags{ "RenderType" = "Opaque" "Queue" = "Background" }  

RenderType = Opaque means this object does not have any transparency on it.
Queue = Background means whatever object has this shader, it's order in the render queue is in the beginning, so that this object will be rendered before anything else is rendered.
This type of ordering is needed inorder to draw transparent things that will be drawn later by the GPU. This Queue is usually used by Skyboxes.
Some flags have to be set.

  ZWrite Off  
  Fog{ Mode Off }  
  Cull Off  

ZWrite off means don't use depth data to determine whether to display this fragment.
Fog { Mode off } means fragment colour not affected by fog.
Cull off means both faces will be drawn of that object.
Preparing the structs :- used to get input data from unity regarding the object the shader is on. This data can be positions, normals and texture coordinates.

  struct appdata  
  {  
       float4 position : POSITION;  
       float3 texcoord : TEXCOORD0;  
  };  
  struct v2f  
  {  
       float4 position : SV_POSITION;  
       float3 texcoord : TEXCOORD0;  
  };  

The declaration of properties in the CG Program.

  fixed3 _SkyColor1;  
  fixed3 _SkyColor2;  
  fixed3 _SkyColor3;  
  fixed3 _SkyColor4;  
  half _Transition;  
  half _BaseLevel;  
  int _GradientExponent;  
  fixed3 _SunColor;  
  int _Scaling;  
  half _SunRim;  

The vertex shader ( Nothing Special Happens Here )

  v2f vert(appdata v)  
 {  
      v2f o;  
      o.position = UnityObjectToClipPos(v.position);  
      o.texcoord = v.texcoord;  
      return o;  
 }  

The fragment shader ( The Meat Of The Shader )

  fixed4 frag(v2f i) : COLOR  
  {  
        half3 v = normalize(i.texcoord);  
        half p = pow(v.y + _BaseLevel, _GradientExponent);  
        fixed3 topCol = lerp(_SkyColor1, _SkyColor3, _Transition);  
        fixed3 bottomCol = lerp(_SkyColor2, _SkyColor4, _Transition);  
        half dotVal = dot(v, _WorldSpaceLightPos0.xyz);  
        if (dotVal > _SunRim)  
          return lerp(fixed4(lerp(topCol, bottomCol, p), 1.0), fixed4(_SunColor,1.0), pow(dotVal, _Scaling));  
       else  
         return fixed4(lerp(topCol, bottomCol, p), 1.0);  
  }  

 half3 v = normalize(i.texcoord);  

now v contains 3 float values relating to the texture coordinates which have been normalized.

half p = pow(v.y + _BaseLevel, _GradientExponent);

determines the y axis value from which the transition should happen from topCol to bottomCol.
The larger the value of _GradientExponent the sharper the transition.

fixed3 topCol = lerp(_SkyColor1, _SkyColor3, _Transition);  
fixed3 bottomCol = lerp(_SkyColor2, _SkyColor4, _Transition);

topColour  and bottomColour are determined by the _Transition value.
_Transition value goes from 0.0 to +1.0 and the output will be _SkyColor3 if _Transition value is 1 for topCol and _SkyColor1 if _Transition value is 0.

half dotVal = dot(v, _WorldSpaceLightPos0.xyz);

 _WorldSpaceLightPos0.xyz gives the world coordinates of the directional light we have in the scene.
I lied, since this is a directional light we don't care about it's world coordinates, we actually get the direction in which the directional light is pointing.😆
Now the dot product is taken and gives a value from -1.0 to +1.0.If both the fragment's location ( offset from model projection origin acts as direction ) and direction of directional light is the same then we get a value of 1.0, If they are perpendicular we get 0.0 and if they are in exact opposite direction but parallel we get -1.0.

if (dotVal > _SunRim)  
  return lerp(fixed4(lerp(topCol, bottomCol, p), 1.0), fixed4(_SunColor,1.0), pow(dotVal, _Scaling));  
else  
  return fixed4(lerp(topCol, bottomCol, p), 1.0);  

The _SunRim value sets a limitation to what radius the sun can extend to. Only if the dotVal is more then the sun is drawn.

fixed4(lerp(topCol, bottomCol, p), 1.0)

The output colour is lerped between the topCol and bottomCol 
with the help of the p value( In case you forgot ).

half p = pow(v.y + _BaseLevel, _GradientExponent);

p is a value holding the point from which horizon should be there, multiplied with a value that determines how smooth or sharp that transition in the horizon is.
You can get the entire code HERE.
If you like programming shaders make sure you check these out : Shader Tutorials
Support Bitshift Programmer by leaving a like on Bitshift Programmer Facebook Page and be updated as soon as there is a new blog post.
If you have any questions that you might have about shaders or unity development in general don't be shy and leave a message on my facebook page or down in the comments.